How to override package version

16

I just took a look at the source of the houdini package and it looks like

{ callPackage, buildFHSUserEnv, undaemonize }:

let
  houdini-runtime = callPackage ./runtime.nix { };
in buildFHSUserEnv rec {
  name = "houdini-${houdini-runtime.version}";

  extraBuildCommands = ''
    mkdir -p $out/usr/lib/sesi
  '';

  runScript = "${undaemonize}/bin/undaemonize ${houdini-runtime}/bin/houdini";
}

I’m not familiar with the details of buildFHSUserEnv but it looks to me as though the houdini package is itself just a thin wrapper around houdini-runtime and so what you’ve done with your override is produced a hybrid package that tries to install houdini-runtime-17.5.258 but also depends on houdini-runtime-17.0.352.

Without any testing on my part, I’d wager that you need to instead duplicate the default.nix while overriding the runtime portion. This might look like the following (completely untested):

self: super:
let
  orig-houdini-runtime = super.callPackage <nixpkgs/pkgs/applications/misc/houdini/runtime.nix> { };
  houdini-runtime = orig-houdini-runtime.overrideAttrs (old: rec {
    name = "houdini-runtime-${version}";
    version = "17.5.258";
    src = super.requireFile rec {
      name = "houdini-${version}-linux_x86_64_gcc6.3.tar.gz";
      sha256 = "1pibc0gmjyw0s9vj0f77idfh41kgjk7l0qfjg4ahlxh84pwhsvzx";
      message = ''
        This nix expression requires that ${name} is already part of the store.
        Download it from https://sidefx.com and add it to the nix store with:

            nix-prefetch-url <URL>

        This can't be done automatically because you need to create an account on
        their website and agree to their license terms before you can download
        it. That's what you get for using proprietary software.
      '';
    };
  });
in
{
  houddini = super.buildFHSUserEnv rec {
    name = "houdini-${houdini-runtime.version}";

    extraBuildCommands = ''
      mkdir -p $out/usr/lib/sesi
    '';

    runScript = "${self.undaemonize}/bin/undaemonize ${houdini-runtime}/bin/houdini";
  };
}