# Using Dropbox on Nixos

**URL:** https://discourse.nixos.org/t/using-dropbox-on-nixos/387
**Category:** Help
**Created:** [June 22, 2018, 7:23am UTC](https://discourse.nixos.org/t/using-dropbox-on-nixos/387 "2018-06-22T07:23:09Z")
**Posts on this page:** 1
**Showing post:** 6

<div class="post-metadata">

### Author: ![peterhoeg](https://discourse.nixos.org/user_avatar/discourse.nixos.org/peterhoeg/32/137_2.png) [@peterhoeg](https://discourse.nixos.org/u/peterhoeg)
#### Post date: [January 2, 2019, 2:34am UTC](https://discourse.nixos.org/t/using-dropbox-on-nixos/387/6 "2019-01-02T02:34:40Z")

</div>

Sure, this is how I use it:

```nix
{ config, lib, pkgs, ... }:

{
  environment.systemPackages = with pkgs; [
    # dropbox - we don't need this in the environment. systemd unit pulls it in
    dropbox-cli
  ];

  networking.firewall = {
    allowedTCPPorts = [17500];
    allowedUDPPorts = [17500];
  };

  systemd.user.services.dropbox = {
    description = "Dropbox";
    after = ["xembedsniproxy.service"];
    wants = ["xembedsniproxy.service"];
    wantedBy = ["graphical-session.target"];
    environment = {
      QT_PLUGIN_PATH = "/run/current-system/sw/" + pkgs.qt5.qtbase.qtPluginPrefix;
      QML2_IMPORT_PATH = "/run/current-system/sw/" + pkgs.qt5.qtbase.qtQmlPrefix;
    };
    serviceConfig = {
      ExecStart = "${pkgs.dropbox.out}/bin/dropbox";
      ExecReload = "${pkgs.coreutils.out}/bin/kill -HUP $MAINPID";
      KillMode = "control-group"; # upstream recommends process
      Restart = "on-failure";
      PrivateTmp = true;
      ProtectSystem = "full";
      Nice = 10;
    };
  };
}

```

---

_[View the full topic](https://discourse.nixos.org/t/using-dropbox-on-nixos/387)._