Convert appimage to nixos package

fredc30 · May 2, 2026, 3:34pm

Hello!!!

For a couple of day, I start to “play“ with my nixos config. That’s fun when you use debian daily.

Software install is comfortable, easy and efficient.

I tried to convert an appimage working fine with appimage-run. I read https://wiki.nixos.org/wiki/Appimage and several wiki but still don’t understand where I should put this piece of code in my config.

If you got a process or wiki that explains to newbies. You’re welcome. Or the page in the user manual… or just clue….

Thanks a lot!

bitbloxhub · May 2, 2026, 5:14pm

I assume you mean the appimageTools.wrapType2 block? I’d just replace the URL, hash, and meta, put it in pkgs/<package-name>.nix, and use (pkgs.callPackage ./pkgs/<package-name>.nix { }) in environment.systemPackages. Out of curiosity, what app do you need this appimage for?

fredc30 · May 2, 2026, 7:08pm

Thanks for your reply.

Scenari opale for multisupport document a great tool for multi support ressources.

and use (pkgs.callPackage ./pkgs/.nix { }) in environment.systemPackages

I’ll try …

Thanks !!

fredc30 · May 2, 2026, 9:58pm

Great ! That’s a part of solution. Now I need to find how to create a .desktop created by the script software usually. The build failed because .desktop does’nt exist. But I can start the app by the terminal. That’s a great jump! Thanks!

bitbloxhub · May 2, 2026, 10:26pm

Looks like you’ll want to:

Make appimageContents equal appimageTools.extractType2 { inherit pname version src; }; in the let block.
Replace extraInstallCommands with this:

install -m 444 -D "${appimageContents}/opale25.desktop" "$out/share/applications/opale25.desktop"
substituteInPlace $out/share/applications/opale25.desktop \
  --replace-fail 'Exec=AppRun' 'Exec=opale'

Also you should know about the --keep-failed option to nix-build and nix build. It’s helpful for debugging stuff like this.

My working derivation

{
  lib,
  appimageTools,
  fetchurl,
}:

let
  version = "25.1.2";
  pname = "opale";

  src = fetchurl {
    url = "https://download.scenari.software/Opale@25.1.2/Opale25_en-US.AppImage";
    hash = "sha256-byB0eegSz5GpmD59IGok3U4RelHF5Q6Zuw4PBadxOgQ=";
  };

  appimageContents = appimageTools.extractType2 { inherit pname version src; };
in
appimageTools.wrapType2 rec {
  inherit pname version src;

  extraInstallCommands = ''
    install -m 444 -D "${appimageContents}/opale25.desktop" "$out/share/applications/opale25.desktop"
    substituteInPlace $out/share/applications/opale25.desktop \
      --replace-fail 'Exec=AppRun' 'Exec=opale'
  '';
}

fredc30 · May 3, 2026, 8:22am

I use –show-trace but I just start and need learn the”useful” options

Now the build works properly! I got a white icon instead of opale icon but I’ll try to find.

I think I need to read and learn deeply

Data · May 3, 2026, 9:16am

Just made a symbolic link.

cd Desktop/
ln -s /user/Appimage-Directory/File.Appimage DeskyopNameYouWant

bitbloxhub · May 3, 2026, 7:47pm

Looks like you want to do something with symlinking/copying ${appimageContents}/usr/share/icons to $out inextraInstallCommands.

From a quick github code search (Also something useful to know if you want to use nix, very helpful to see how others do things):

github.com/fufexan/nix-gaming

pkgs/titanfall/viper.nix

57ab0906f


      
              libgpg-error
              libGL
            ];
          in
          appimageTools.wrapType2 {
            inherit pname version src;
            multiPkgs = null; # no 32bit needed
            extraPkgs = p: (appimageTools.defaultFhsEnvArgs.multiPkgs p) ++ libs;
            extraInstallCommands = ''
              install -m 444 -D ${appimageContents}/${pname}.desktop -t $out/share/applications
              cp -r ${appimageContents}/usr/share/icons $out/share
          
              # cringe hack to get wrapProgram working in extraInstallCommands
              source "${dieHook}/nix-support/setup-hook"
              source "${makeWrapper}/nix-support/setup-hook"
          
              mv $out/bin/${pname} $out/bin/${pname}-${version}
              makeWrapper $out/bin/${pname}-${version} $out/bin/${pname} \
                --unset APPIMAGE \
                --unset APPDIR
            '';

github.com/CatalystDevOrg/Catalyst

package.nix

2c7b82acc


      
          nativeBuildInputs = [ makeWrapper ];
          
          installPhase = ''
            runHook preInstall
          
            mkdir -p $out/bin $out/share/${pname} $out/share/applications
            mkdir -p $out/share/${pname}/resources/
          
            cp -a ${appimageContents}/locales $out/share/${pname}
            cp -a ${appimageContents}/catalyst.desktop $out/share/applications/${pname}.desktop
            cp -a ${appimageContents}/usr/share/icons $out/share
            asar extract ${appimageContents}/resources/app.asar resources/
            rm -rf resources/.github
            rm -rf resources/.vscode
            rm -rf resources/.eslintrc.json
            rm -rf resources/.gitignore
            rm -rf resources/.pnpm-debug.log
            rm -rf resources/contributing.md
            rm -rf resources/pnpm-lock.yaml
            rm -rf resources/README.md
            rm -rf resources/tailwind.config.js

github.com/iynaix/dotfiles

modules/gui/helium/_package.nix

5204658ef


      
          // {
            nativeBuildInputs = [ makeWrapper ];
            extraInstallCommands = /* sh */ ''
              wrapProgram $out/bin/${pname} \
                  --set-default XDG_DATA_HOME "$HOME/.local/share" \
                  --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations --enable-wayland-ime=true}}"
          
              install -m 444 -D ${appimageContents}/${pname}.desktop -t $out/share/applications
              substituteInPlace $out/share/applications/${pname}.desktop \
                --replace 'Exec=AppRun' 'Exec=${pname}'
              cp -r ${appimageContents}/usr/share/icons $out/share
            '';
          
            # pass through files from the root fs
            extraBwrapArgs = [
              # chromium policies
              "--ro-bind-try /etc/chromium/policies/managed/default.json /etc/chromium/policies/managed/default.json"
              # xdg scheme-handlers
              "--ro-bind-try /etc/xdg/ /etc/xdg/"
            ];

TLATER · May 4, 2026, 6:29am

--show-trace is almost always useless and just hides the actual issue under a few thousand lines of repetitive traces; I would recommend forgetting that flag exists.

I think I recall about two times the issue was actually hidden in traces instead of plainly obvious in the normal output over the last 10 years.

fredc30 · May 4, 2026, 4:24pm

Thanks for your help!!!

Finally, works fine!!

After logout and login my account…

I think I should spend couple of hours to increase my knowledge on Nixos.

the code…

{ 
 lib, 
 appimageTools, 
 fetchurl, 
}: 

let 
 version = "25.1.2";
 pname = "opale25";

 src = fetchurl {
   url = "https://download.scenari.software/Opale@25.1.2/Opale25_en-US.AppImage";
   hash = "sha256-byB0eegSz5GpmD59IGok3U4RelHF5Q6Zuw4PBadxOgQ=";
 }; 

 appimageContents = appimageTools.extractType2 { inherit pname version src; };
in 
appimageTools.wrapType2 rec { 
 extraInstallCommands = ''
 inherit pname version src; 

   install -m 444 -D ${appimageContents}/${pname}.desktop -t $out/share/applications 
   cp -r ${appimageContents}/usr/share/icons $out/share 
   substituteInPlace $out/share/applications/opale25.desktop \ 
     --replace-fail 'Exec=AppRun' 'Exec=${pname}' 
 ''; 
}

waffle8946 · May 4, 2026, 5:53pm

Unfortunately non-trivial module system errors are usually hidden and require it, but yes, it’s better to avoid by default unless you know the trimmed log is missing crucial info.