Dank Material Shell programs.quickshell does not exist

Help
1

I’m trying to install dank material shell with home manager and seem to be running into a problem where ‘home-manager.users.user.programs.quickshell does not exist’

Here is my flake

  description = "Flake for my machines";
  inputs = {
    nixpkgs.url = "nixpkgs/nixos-25.05";
    nixpkgs-unstable.url = "nixpkgs/nixos-unstable";

    nvf = {
      url = "github:notashelf/nvf";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    hyprland = {
      url = "github:hyprwm/Hyprland";
      inputs.nixpkgs.follows = "nixpkgs-unstable";
    };

    nixcord = {
      url = "github:kaylorben/nixcord";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    sops-nix = {
      url = "github:mic92/sops-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    dgop = {
      url = "github:AvengeMedia/dgop";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    dms-cli = {
      url = "github:AvengeMedia/danklinux";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    dankMaterialShell = {
      url = "github:AvengeMedia/DankMaterialShell";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.dgop.follows = "dgop";
      inputs.dms-cli.follows = "dms-cli";
    };

    niri = {
      url = "github:sodiboo/niri-flake";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    home-manager = {
      url = "github:nix-community/home-manager/release-25.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };
  outputs = inputs @ {nixpkgs, ...}: {
    nixosConfigurations = {
      majula = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          {
            _module.args = {inherit inputs;};
          }
          ./hosts/majula/configuration.nix
          inputs.home-manager.nixosModules.home-manager
          {
            home-manager = {
              useGlobalPkgs = true;
              useUserPackages = true;
              users.alec = import ./hosts/majula/home.nix;
              backupFileExtension = "backup";
              extraSpecialArgs = {inherit inputs;};
            };
          }
        ];
      };
      installerIso = nixpkgs.lib.nixosSystem {
        specialArgs = {inherit inputs;};
        modules = [
          ./hosts/isoImage/configuration.nix
        ];
      };
    };
  };
}

Here is the module for dms

{
  pkgs,
  config,
  inputs,
  ...
}: {
  imports = [
    inputs.dankMaterialShell.homeModules.dankMaterialShell.default
    inputs.dankMaterialShell.homeModules.dankMaterialShell.niri
  ];

  programs.dankMaterialShell = {
    enable = true;
  };
}

My home.nix

{
  config,
  pkgs,
  inputs,
  ...
}: {
  imports = [
    ../../home/programs/git
    ../../home/programs/kitty
    ../../home/programs/shell
    ../../home/programs/nvf
    ../../home/programs/discord

    ../../home/system/dms
    ../../home/system/hyprland
    ../../home/system/niri
    #    ../../home/system/vicinae

    ./variables.nix

    ./secrets
  ];

  home.username = "alec";
  home.homeDirectory = "/home/alec";
  home.stateVersion = "25.05";

  home.packages = [
  ];
}

And the error

building the system configuration...
error:
       … while calling the 'head' builtin
         at /nix/store/d7s7pkgp0shkac0qwf2f9w956fi6rh1i-source/lib/attrsets.nix:1571:13:
         1570|           if length values == 1 || pred here (elemAt values 1) (head values) then
         1571|             head values
             |             ^
         1572|           else

       … while evaluating the attribute 'value'
         at /nix/store/d7s7pkgp0shkac0qwf2f9w956fi6rh1i-source/lib/modules.nix:1083:7:
         1082|     // {
         1083|       value = addErrorContext "while evaluating the option `${showOption loc}':" value;
             |       ^
         1084|       inherit (res.defsFinal') highestPrio;

       … while evaluating the option `system.build.toplevel':

       … while evaluating definitions from `/nix/store/d7s7pkgp0shkac0qwf2f9w956fi6rh1i-source/nixos/modules/system/activation/top-level.nix':

       … while evaluating the option `assertions':

       … while evaluating definitions from `/nix/store/a4la088hi5id7sw77gy9zdvwn83dgczz-source/nixos/common.nix':

       (stack trace truncated; use '--show-trace' to show the full, detailed trace)

       error: The option `home-manager.users.alec.programs.quickshell' does not exist. Definition values:
       - In `/nix/store/hq8d6xbl99vbviyfyjny4sjfzxpi00j4-source/nix/default.nix'

I am still new to Nix and NixOS so any help would be greatly appreciated. Thank you.

2

Did you import DMS file into an instead of system? Your error is about modules cannot find home-manager options

3

It wasnt anything involving the imports. To get the error to clear I had to change my home manager version to the unstable branch due to quickshell not being in the 25.05 branch.

Now though im getting a new error

error:
       … while calling the 'head' builtin
         at /nix/store/58hq018zklzi0jyjfks7g4q02bckvp7j-source/lib/attrsets.nix:1571:13:
         1570|           if length values == 1 || pred here (elemAt values 1) (head values) then
         1571|             head values
             |             ^
         1572|           else

       … while evaluating the attribute 'value'
         at /nix/store/58hq018zklzi0jyjfks7g4q02bckvp7j-source/lib/modules.nix:1083:7:
         1082|     // {
         1083|       value = addErrorContext "while evaluating the option `${showOption loc}':" value;
             |       ^
         1084|       inherit (res.defsFinal') highestPrio;

       … while evaluating the option `system.build.toplevel':

       … while evaluating definitions from `/nix/store/58hq018zklzi0jyjfks7g4q02bckvp7j-source/nixos/modules/system/activation/top-level.nix':

       … while evaluating the option `warnings':

       … while evaluating definitions from `/nix/store/58hq018zklzi0jyjfks7g4q02bckvp7j-source/nixos/modules/system/boot/systemd.nix':

       … while evaluating the option `systemd.services.home-manager-alec.serviceConfig':

       … while evaluating definitions from `/nix/store/ijblcn7dhnzaqvz1panymwmwz72dnpki-source/nixos':

       … while evaluating the option `home-manager.users.alec.home.file.".manpath".source':

       … while evaluating definitions from `/nix/store/ijblcn7dhnzaqvz1panymwmwz72dnpki-source/modules/files.nix':

       … while evaluating the option `home-manager.users.alec.home.file.".manpath".text':

       … while evaluating definitions from `/nix/store/ijblcn7dhnzaqvz1panymwmwz72dnpki-source/modules/programs/man.nix':

       … while evaluating the option `home-manager.users.alec.home.packages':

       … while evaluating definitions from `/nix/store/ijblcn7dhnzaqvz1panymwmwz72dnpki-source/modules/programs/quickshell.nix':

       … while evaluating the option `home-manager.users.alec.programs.quickshell.package':

       … while evaluating definitions from `/nix/store/yzj5fww60y4xj7wplarqmqqfm2bn16nd-source/nix/default.nix':

       … while evaluating the option `home-manager.users.alec.programs.dankMaterialShell.quickshell.package':

       (stack trace truncated; use '--show-trace' to show the full, detailed trace)

       error: quickshell cannot be found in pkgs
4

Your configuration is built off of the stable Nixpkgs revision, pkgs in the module system does not have quickshell. Change programs.quickshell.package = pkgs-unstable.quickshell or something.

5

Here is the final working flake and dms/default.nix file. Home.nix mostly remained unchanged.

{
  description = "Flake for my machines";
  inputs = {
    nixpkgs.url = "nixpkgs/nixos-25.05";
    nixpkgs-unstable.url = "nixpkgs/nixos-unstable";

    nvf = {
      url = "github:notashelf/nvf";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    hyprland = {
      url = "github:hyprwm/Hyprland";
      inputs.nixpkgs.follows = "nixpkgs-unstable";
    };

    nixcord = {
      url = "github:kaylorben/nixcord";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    sops-nix = {
      url = "github:mic92/sops-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    dgop = {
      url = "github:AvengeMedia/dgop";
      inputs.nixpkgs.follows = "nixpkgs-unstable";
    };

    dms-cli = {
      url = "github:AvengeMedia/danklinux";
      inputs.nixpkgs.follows = "nixpkgs-unstable";
    };

    dankMaterialShell = {
      url = "github:AvengeMedia/DankMaterialShell";
      inputs.nixpkgs.follows = "nixpkgs-unstable";
      inputs.dgop.follows = "dgop";
      inputs.dms-cli.follows = "dms-cli";
    };

    niri = {
      url = "github:sodiboo/niri-flake";
      inputs.nixpkgs.follows = "nixpkgs-unstable";
    };

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs-unstable";
    };
  };
  outputs = inputs @ {
    nixpkgs,
    nixpkgs-unstable,
    ...
  }: {
    nixosConfigurations = {
      majula = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          {
            _module.args = {inherit inputs;};
          }
          ./hosts/majula/configuration.nix
          inputs.home-manager.nixosModules.home-manager
          {
            home-manager = {
              useGlobalPkgs = true;
              useUserPackages = true;
              users.alec = import ./hosts/majula/home.nix;
              backupFileExtension = "backup";
              extraSpecialArgs = {
                inherit inputs;
                pkgs-unstable = import nixpkgs-unstable {
                  system = "x86_64-linux";
                  config.allowUnfree = true;
                };
              };
            };
          }
        ];
      };
      installerIso = nixpkgs.lib.nixosSystem {
        specialArgs = {inherit inputs;};
        modules = [
          ./hosts/isoImage/configuration.nix
        ];
      };
    };
  };
}

{
  pkgs,
  pkgs-unstable,
  config,
  inputs,
  ...
}: {
  imports = [
    inputs.dankMaterialShell.homeModules.dankMaterialShell.default
    inputs.dankMaterialShell.homeModules.dankMaterialShell.niri
  ];

  programs.dankMaterialShell = {
    enable = true;
    quickshell.package = pkgs-unstable.quickshell;
  };
}