Davinci Resolve Studio install Issues

BlastboomStrice · April 15, 2025, 1:20pm

Just an update, hardware.opengl no longer exist, it has been renamed to hardware.graphics and I think that

hardware.opengl = {
    enable = true;
    driSupport = true;
    driSupport32Bit = true;
  };

has become:

  hardware.graphics = {
    enable = true;
    enable32Bit = true;
  };

EDIT: THIS SEEMS TO HAVE FIXED MY GPU DRIVERS IN GENERAL, THANKS!!
I will probably update my question here How to use discrete amd gpu in bottles (or globally) - #5 by langfingaz
The funny thing is that davinci resolve still cant detect a gpu, lol

LanceHardwoodXXX · June 3, 2025, 3:24pm

Hello,

Just a quick question regarding DaVinci Resolve Studio on NixOS. I have it running fine with my AMD 9070 XT GPU, but I’m encountering a couple of issues:

LUT Import Issues: I found the existing LUT files in ~/.local/share/DaVinciResolve/.LUT/. However, if I add new LUTs to this folder, they are not detected by DaVinci Resolve. Renaming existing LUTs in this folder also doesn’t seem to have any effect. I’ve tried “Color Management → Update Folder” without success, and I’m unable to open the LUT folder directly from within DaVinci Resolve. Could the “real” LUTs be located within the Nix store itself, and perhaps that’s why new ones aren’t being picked up? Any ideas would be greatly appreciated.
H.264/H.265 Export Missing: Despite having a Studio license, I’m unable to export to H.264 or H.265 (though working with these codecs for editing is possible). I’m currently using a workaround by exporting to ProRes and then converting with ffmpeg. I suspect the encoder plugins might be missing from the DaVinci Resolve package on NixOS.

Has anyone else experienced these issues or have any insights into resolving them?

Thanks in advance!

waffle8946 · June 4, 2025, 1:25pm

That’s not possible on Linux. Use Windows if you need that functionality, or export in another format and use ffmpeg/handbrake/etc to convert it later.

BENDI · June 4, 2025, 1:33pm

The compatibility matrix link suggests that H264/5 encode is indeed possible in the Linux version, but only on NVIDIA GPUs.

waffle8946 · June 4, 2025, 2:35pm

Thanks for the link/nuance, though I wasn’t going to tell them to buy a new GPU (particularly as nvidia still continues to be a pain to use on Linux…) and their current AMD gpu apparently can’t be used to decode said formats. (At least from past forum posts, Davinci doesn’t officially care to support non-NVIDIA on Linux.)

LanceHardwoodXXX · June 5, 2025, 4:22pm

that is fine, I already use the ffmpeg workaround. the first problem with the LUT files is a bigger problem. did somebody found a solution for that?

LanceHardwoodXXX · June 15, 2025, 1:57pm

Just a quick update. Davinci Resolve Studio 20 was released in the unstable branch.
The LUT Problem is fixed.

chrism · June 24, 2025, 6:54pm

I’ve not been able to get DR’s dependencies to compile cleanly on 25.05 or unstable for a while now. The gjs 1.84.2 tests fail like so:

       > Summary of Failures:
       >
       > 39/78 gjs:Debugger / backtrace command         FAIL            0.32s   0/1 subtests passed
       > 40/78 gjs:Debugger / continue command          FAIL            0.31s   0/1 subtests passed
       > 41/78 gjs:Debugger / breakpoint command        FAIL            0.32s   0/1 subtests passed
       > 53/78 gjs:Debugger / detach command            FAIL            0.31s   0/1 subtests passed
       > 61/78 gjs:Debugger / down-up command           FAIL            0.31s   0/1 subtests passed
       > 62/78 gjs:Debugger / delete command            FAIL            0.32s   0/1 subtests passed
       > 64/78 gjs:Debugger / frame command             FAIL            0.31s   0/1 subtests passed
       > 65/78 gjs:Debugger / finish command            FAIL            0.31s   0/1 subtests passed
       > 73/78 gjs:JS / GIMarshalling                   FAIL            1.02s   730/731 subtests passed

I’m kinda surprised it works for anyone else. I’ve been backwatered on the 24.11 version since 25.05 was released (it uses gjs 1.82.1)

matkijahenkilo · October 13, 2025, 10:18am

DaVinci Resolve - ArchWiki mentions that it is possible to export h264/5 on linux, it says that you need to use this plugin: GitHub - EdvinNilsson/ffmpeg_encoder_plugin: FFmpeg Encoder Plugin for DaVinci Resolve Studio, but I haven’t seen this plugin being mentioned anywhere on nixpkgs

in my tests with this plugin installed in arch linux I saw that I can select mp4 format and h264 codec, but I didn’t try exporting the video with these settings. Without this plugin these options weren’t visible

matkijahenkilo · October 21, 2025, 3:46am

I managed to include said plugin to davinci doing the following:

make this derivation:

ffmpeg-encoder-plugin = pkgs.stdenv.mkDerivation (finalAttrs: {
    pname = "ffmpeg-encoder-plugin";
    version = "1.1.0";

    src = pkgs.fetchFromGitHub {
      owner = "EdvinNilsson";
      repo = "ffmpeg_encoder_plugin";
      tag = "v${finalAttrs.version}";
      hash = "sha256-orghLIzz9rUnUwka9C71Z2nj+qxHuggrKNlYjLKswQw=";
    };

    nativeBuildInputs = with pkgs; [
      cmake
      ffmpeg-full
    ];

    buildInputs = with pkgs; [ ffmpeg ];

    installPhase = ''
      runHook preInstall

      mkdir -p $out
      cp ffmpeg_encoder_plugin.dvcp $out/

      runHook postInstall
    '';
  });

then copy it to davinci’s plugin path with cp ${ffmpeg-encoder-plugin}/ffmpeg_encoder_plugin.dvcp $out/IOPlugins/ffmpeg_encoder_plugin.dvcp.bundle/Contents/Linux-x86-64/ in davinci’s postInstall script

here’s my davinci module:

{
  inputs,
  lib,
  pkgs,
  ...
}:
let
  ffmpeg-encoder-plugin = pkgs.stdenv.mkDerivation (finalAttrs: {
    pname = "ffmpeg-encoder-plugin";
    version = "1.1.0";

    src = pkgs.fetchFromGitHub {
      owner = "EdvinNilsson";
      repo = "ffmpeg_encoder_plugin";
      tag = "v${finalAttrs.version}";
      hash = "sha256-orghLIzz9rUnUwka9C71Z2nj+qxHuggrKNlYjLKswQw=";
    };

    nativeBuildInputs = with pkgs; [
      cmake
      ffmpeg-full
    ];

    buildInputs = with pkgs; [ ffmpeg ];

    installPhase = ''
      runHook preInstall

      mkdir -p $out
      cp ffmpeg_encoder_plugin.dvcp $out/

      runHook postInstall
    '';
  });

  davinci-resolve-studio =
    let
      davinci-patched = pkgs.davinci-resolve-studio.davinci.overrideAttrs (old: {
        # Note: $out IS /opt/resolve
        postInstall = ''
          mkdir -p $out/IOPlugins/ffmpeg_encoder_plugin.dvcp.bundle/Contents/Linux-x86-64/
          cp ${ffmpeg-encoder-plugin}/ffmpeg_encoder_plugin.dvcp $out/IOPlugins/ffmpeg_encoder_plugin.dvcp.bundle/Contents/Linux-x86-64/
        '';
      });
    in

    # the following was copied from davinci's derivation from nixpkgs.
    # if davinci updates, this should be updated too
    # but remember to replace "davinci" with "davinci-patched"
    pkgs.buildFHSEnv {
      inherit (davinci-patched) pname version;

      targetPkgs =
        pkgs:
        with pkgs;
        [
          alsa-lib
          aprutil
          bzip2
          dbus
          expat
          fontconfig
          freetype
          glib
          libGL
          libGLU
          libarchive
          libcap
          librsvg
          libtool
          libuuid
          libxcrypt # provides libcrypt.so.1
          libxkbcommon
          nspr
          ocl-icd
          opencl-headers
          python3
          python3.pkgs.numpy
          udev
          xdg-utils # xdg-open needed to open URLs
          xorg.libICE
          xorg.libSM
          xorg.libX11
          xorg.libXcomposite
          xorg.libXcursor
          xorg.libXdamage
          xorg.libXext
          xorg.libXfixes
          xorg.libXi
          xorg.libXinerama
          xorg.libXrandr
          xorg.libXrender
          xorg.libXt
          xorg.libXtst
          xorg.libXxf86vm
          xorg.libxcb
          xorg.xcbutil
          xorg.xcbutilimage
          xorg.xcbutilkeysyms
          xorg.xcbutilrenderutil
          xorg.xcbutilwm
          xorg.xkeyboardconfig
          zlib
        ]
        ++ [ davinci-patched ];

      extraPreBwrapCmds = ''
        mkdir -p ~/.local/share/DaVinciResolve/license || exit 1
        mkdir -p ~/.local/share/DaVinciResolve/Extras || exit 1
      '';

      extraBwrapArgs = [
        ''--bind "$HOME"/.local/share/DaVinciResolve/license ${davinci-patched}/.license''
        ''--bind "$HOME"/.local/share/DaVinciResolve/Extras ${davinci-patched}/Extras''
      ];

      runScript = "${lib.getExe pkgs.bash} ${pkgs.writeText "davinci-wrapper" ''
        export QT_XKB_CONFIG_ROOT="${pkgs.xkeyboard_config}/share/X11/xkb"
        export QT_PLUGIN_PATH="${davinci-patched}/libs/plugins:$QT_PLUGIN_PATH"
        export LD_LIBRARY_PATH=$LD_LIBRARY_PATH:/usr/lib:/usr/lib32:${davinci-patched}/libs
        ${davinci-patched}/bin/resolve
      ''}";

      extraInstallCommands = ''
        mkdir -p $out/share/applications $out/share/icons/hicolor/128x128/apps
        ln -s ${davinci-patched}/share/applications/*.desktop $out/share/applications/
        ln -s ${davinci-patched}/graphics/DV_Resolve.png $out/share/icons/hicolor/128x128/apps/davinci-resolve-studio.png
      '';

      passthru = {
        inherit davinci-patched;
        updateScript = lib.getExe (
          pkgs.writeShellApplication {
            name = "update-davinci-resolve";
            runtimeInputs = [
              pkgs.curl
              pkgs.jq
              pkgs.common-updater-scripts
            ];
            text = ''
              set -o errexit
              drv=pkgs/by-name/da/davinci-resolve/package.nix
              currentVersion=${lib.escapeShellArg davinci-patched.version}
              downloadsJSON="$(curl --fail --silent https://www.blackmagicdesign.com/api/support/us/downloads.json)"

              latestLinuxVersion="$(echo "$downloadsJSON" | jq '[.downloads[] | select(.urls.Linux) | .urls.Linux[] | select(.downloadTitle | test("DaVinci Resolve")) | .downloadTitle]' | grep -oP 'DaVinci Resolve \K\d+\.\d+(\.\d+)?' | sort | tail -n 1)"
              update-source-version davinci-resolve "$latestLinuxVersion" --source-key=davinci.src

              # Since the standard and studio both use the same version we need to reset it before updating studio
              sed -i -e "s/""$latestLinuxVersion""/""$currentVersion""/" "$drv"

              latestStudioLinuxVersion="$(echo "$downloadsJSON" | jq '[.downloads[] | select(.urls.Linux) | .urls.Linux[] | select(.downloadTitle | test("DaVinci Resolve")) | .downloadTitle]' | grep -oP 'DaVinci Resolve Studio \K\d+\.\d+(\.\d+)?' | sort | tail -n 1)"
              update-source-version davinci-resolve-studio "$latestStudioLinuxVersion" --source-key=davinci.src
            '';
          }
        );
      };
    };
in
{
  environment.systemPackages = [ davinci-resolve-studio ];
  # you should configure your system to make davinci work here
  # such as this, in case of amd card
  environment.variables = {
    RUSTICL_ENABLE = "radeonsi";
  };
  hardware = {
    amdgpu.opencl.enable = true;
    graphics.extraPackages = with pkgs; [
      mesa.opencl
    ];
  };
}

the result was that I was able to export videos to H264/5 & AV1, but the sound codec was only possible to export as FLAC

sk4g · November 19, 2025, 7:24pm

Does anyone have Davinci Resolve working with rocm on NixOS Unstable or channel 25.05 or later?
In 25.05 rocmPackages_5 were removed. I pinned rocmPackages_5.clr from channel 24.11, but still have crashes at launch.

With rocm 6 DR initialization completes and crashes when opening a project, with logs complaining about DR unable to find rocm 5.

This is what I have so far,

davinci-resolve.nix

{ config, pkgs, ... }:

let
  # Pin rocmPackages.clr to version 5.7.1 for DaVinci Resolve Studio compatibility
  rocmPackages_5_7_1 = import (builtins.fetchTarball {
    name = "nixpkgs-pinned-5.7.1";
    url = "https://github.com/NixOS/nixpkgs/archive/a3ed7406349a9335cb4c2a71369b697cecd9d351.tar.gz";
    sha256 = "1qmbd98ywmywsacr7b4b17k7pyvmhmlq1avci92ahwx1frq00g1w";
  }) {
    system = config.nixpkgs.system;
  };
  rocmPackages_5.clr = rocmPackages_5_7_1.rocmPackages.clr;
in
{
  nixpkgs.overlays = [
    # Override ROCm packages to use version 5.7.1 for DaVinci Resolve compatibility
    (final: prev: {
      rocmPackages = prev.rocmPackages // {
        clr = rocmPackages_5.clr;
      };
    })
    (final: prev: {
      davinci-resolve-studio = prev.davinci-resolve-studio.override (old: {
        buildFHSEnv = a: (prev.buildFHSEnv (a // {
          extraBwrapArgs = a.extraBwrapArgs ++ [
            ''--bind /run/opengl-driver/etc/OpenCL /etc/OpenCL''
            # redirect Resolve's "Extras" dir away from /nix/store to a writable location
            ''--bind ${config.xdg.dataHome or "$HOME/.local/share"}/DaVinciResolve/Extras /opt/resolve/Extras''
          ];
        }));
      });
    })
  ];

  hardware.graphics = {
    enable32Bit = true;
    extraPackages = with pkgs; [
      rocmPackages_5.clr
      rocmPackages_5.clr.icd
    ];
  };
  systemd.tmpfiles.rules = [
    "L+    /opt/rocm/hip   -    -    -     -    ${rocmPackages_5.clr}"
    ];
}

rocm 5 package pin logs

==========[CRASH DUMP]==========
#TIME Wed Nov 19 13:17:04 2025 - Uptime 00:00:00 (hh:mm:ss)
#PROGRAM_NAME DaVinci Resolve Studio v20.2.3.0006 (Linux/Clang x86_64)
#BMD_ARCHITECTURE x86_64
#BMD_BUILD_UUID 924275c8-3ec6-42e9-a84a-def97e8e5c18
#BMD_GIT_COMMIT 14afe2c9cac879ba880bb57b3d6987912c4679c4
#BMD_UTIL_VERSION 20.2.3.0006
#OS Linux

/nix/store/k2agn8ahpgxip4dyrnqby98apvxp74bf-davinci-resolve-studio-20.2.3/bin/resolve() [0x6008129]
/nix/store/k2agn8ahpgxip4dyrnqby98apvxp74bf-davinci-resolve-studio-20.2.3/bin/resolve() [0x60072f2]
/usr/lib/libc.so.6(+0x419c0) [0x7f2bb28419c0]
/usr/lib/libc.so.6(+0x9caac) [0x7f2bb289caac]
/usr/lib/libc.so.6(gsignal+0x1e) [0x7f2bb284190e]
/usr/lib/libc.so.6(abort+0xdf) [0x7f2bb2828942]
/nix/store/k2agn8ahpgxip4dyrnqby98apvxp74bf-davinci-resolve-studio-20.2.3/libs/libQt5Core.so.5(+0x1821c6) [0x7f2bb49821c6]
/nix/store/k2agn8ahpgxip4dyrnqby98apvxp74bf-davinci-resolve-studio-20.2.3/libs/libQt5Core.so.5(_ZNK14QMessageLogger5fatalEPKcz+0xbd) [0x7f2bb496ea5d]
/nix/store/k2agn8ahpgxip4dyrnqby98apvxp74bf-davinci-resolve-studio-20.2.3/libs/plugins/xcbglintegrations/libqxcb-glx-integration.so(+0xb5bb) [0x7f2bb89f65bb]
/nix/store/k2agn8ahpgxip4dyrnqby98apvxp74bf-davinci-resolve-studio-20.2.3/libs/plugins/xcbglintegrations/libqxcb-glx-integration.so(+0x9b28) [0x7f2bb89f4b28]
/nix/store/k2agn8ahpgxip4dyrnqby98apvxp74bf-davinci-resolve-studio-20.2.3/libs/plugins/xcbglintegrations/libqxcb-glx-integration.so(+0x941d) [0x7f2bb89f441d]
/nix/store/k2agn8ahpgxip4dyrnqby98apvxp74bf-davinci-resolve-studio-20.2.3/libs/libQt5Gui.so.5(_ZN14QOpenGLContext6createEv+0x34) [0x7f2bb6f62e44]
/nix/store/k2agn8ahpgxip4dyrnqby98apvxp74bf-davinci-resolve-studio-20.2.3/bin/resolve() [0x385d8b3]
/nix/store/k2agn8ahpgxip4dyrnqby98apvxp74bf-davinci-resolve-studio-20.2.3/bin/resolve() [0x350e718]
/nix/store/k2agn8ahpgxip4dyrnqby98apvxp74bf-davinci-resolve-studio-20.2.3/bin/resolve() [0x350d2f4]
/nix/store/k2agn8ahpgxip4dyrnqby98apvxp74bf-davinci-resolve-studio-20.2.3/bin/resolve() [0x35061ca]
/usr/lib/libc.so.6(+0x2a4d8) [0x7f2bb282a4d8]
/usr/lib/libc.so.6(__libc_start_main+0x8b) [0x7f2bb282a59b]
/nix/store/k2agn8ahpgxip4dyrnqby98apvxp74bf-davinci-resolve-studio-20.2.3/bin/resolve() [0x350464e]
Signal Number = 6