Flakes: idiomatic way to pass inputs to configuration.nix

srid · April 8, 2021, 11:29pm

I use flakes to manage my configuration.nix. To install a custom (non-flakes) package, I specify it as a flake input, and then add it to environment.systemPackages directly as a nixosSystem module.

github.com

srid/nixos-config/blob/08b6cacb50b91d29a2930e124f9ef05405b8fece/flake.nix#L25-L28


      
          # HACK: This should really go under ./features/email
          ({
            environment.systemPackages = [ inputs.himalaya.outputs.defaultPackage.${system} ];
          })

But the above is HACK. As you can see, it belongs to the well-positioned module ./features/email/himalaya-client.nix.

github.com

srid/nixos-config/blob/08b6cacb50b91d29a2930e124f9ef05405b8fece/features/email/himalaya-client.nix#L9


      
          { pkgs, lib, ... }: {
            environment.systemPackages =
              let
                # Wrap himalaya to be aware of ProtonMail's bridge cert.
                himalayaWithSslEnv =
                  pkgs.writeScriptBin "h" ''
                    #!${pkgs.stdenv.shell}
                    export SSL_CERT_FILE=~/.config/protonmail/bridge/cert.pem
                    # HACK: See note in flake.nix
                    exec himalaya $*
                  '';
              in
              [
                himalayaWithSslEnv
              ];
          }

The trouble is, this module apparently cannot be parameterized to pass the inputs from flake.nix.

Maybe I’m missing something. What’s the idiomatic way to approach this?

colemickens · April 9, 2021, 10:42pm

github.com

colemickens/nixcfg/blob/1e6a002d5003135b3039170aa6e1185dc576391d/flake.nix#L107


      
                inherit system overlays;
                config.allowUnfree = true;
              };
            pkgs_ = genAttrs (builtins.attrNames inputs) (inp: genAttrs supportedSystems (sys: pkgsFor inputs."${inp}" sys []));
            fullPkgs_ = genAttrs supportedSystems (sys:
              pkgsFor inputs.nixpkgs sys [ inputs.self.overlay inputs.nixpkgs-wayland.overlay ]);
            mkSystem = pkgs: system: hostname:
              pkgs.lib.nixosSystem {
                system = system;
                modules = [(./. + "/hosts/${hostname}/configuration.nix")];
                specialArgs = { inherit inputs; };
              };
          in rec {
            x = builtins.trace inputs.self.sourceInfo inputs.nixpkgs.sourceInfo;
            devShell = forAllSystems (system:
              pkgs_.nixpkgs.${system}.mkShell {
                name = "nixcfg-devshell";
                nativeBuildInputs = []
                #++ ([ inputs.nix.defaultPackage.${system} ]) # TODO: drop nix input?
                ++ (with pkgs_.stable.${system}; [ cachix ])
                ++ (with inputs.niche.packages.${system}; [ niche ])

Pass it in specialArgs and then it’s just available as an input to your config modules.