Help me understand how to add scopebuddy to my system

Help
1

Hi I have been trying to add the flake for ScopeBuddy into my system. However the instructions seem really obtuse, as is seems like they tell you to add an input into your home-manager. And as far as I could tell, home-manager does not support such functionality. I have managed to add it to my system in a way that evaluates without error, but I am still unable to call it from my shell.

My main flake for reference:

{
  description = "A starter flake to describe my main computer";

  inputs = {
    #NixOS Package Source/Sources
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    home-manager.url = "github:nix-community/home-manager";
    home-manager.inputs.nixpkgs.follows = "nixpkgs";
    musnix.url = "github:musnix/musnix";
    nur.url = "github:nix-community/NUR";
    nur.inputs.nixpkgs.follows = "nixpkgs";
    i915-sriov-dkms.url = "github:/strongtz/i915-sriov-dkms";
    i915-sriov-dkms.inputs.nixpkgs.follows = "nixpkgs";
    scopebuddy.url = "github:HikariKnight/ScopeBuddy";
    scopebuddy.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs = { self, nixpkgs, home-manager, musnix, nur, i915-sriov-dkms, scopebuddy, ... }@inputs: {
    "twilight@twilight-desktop-nixos" = home-manager.lib.homeManagerConfiguration {
      username = "twilight";
      homeDirectory = "/home/twilight";
      configuration = { config, pkgs, scopebuddy, ... }: {
        home.packages = [
          inputs.scopebuddy.packages.${pkgs.system}.default
        ];
      };
    };
    nixosConfigurations.twilight-desktop-nixos = nixpkgs.lib.nixosSystem {
      modules = [
        musnix.nixosModules.musnix
        i915-sriov-dkms.nixosModules.default
        
        ./configuration.nix
        home-manager.nixosModules.home-manager
        {
          home-manager.useGlobalPkgs = true;
          home-manager.useUserPackages = true;
          home-manager.users.twilight = ./home.nix;
        }
      ];
    };
  };
}
2

Are you using HM standalone and as a system module for the very same user on the same machine?

If yes, that kind of setup requires some boilerplate that I do not see the foundation here.

Other than that, the standalone config should work, but of course lacks all the other things you might have.

So you want to use home-manager.extraSpecialArgs = { inherit inputs; }, add inputs to your home.nix’ module args, and then do the suggested addition to home.packages.

3

Thank you so much, I could not find how to “add” inputs to home-manager. I probs should’ve figured it would need to inherit it somehow. By changing my flake.nix to this:

{
  description = "A starter flake to describe my main computer";

  inputs = {
    #NixOS Package Source/Sources
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    home-manager.url = "github:nix-community/home-manager";
    home-manager.inputs.nixpkgs.follows = "nixpkgs";
    musnix.url = "github:musnix/musnix";
    nur.url = "github:nix-community/NUR";
    nur.inputs.nixpkgs.follows = "nixpkgs";
    i915-sriov-dkms.url = "github:/strongtz/i915-sriov-dkms";
    i915-sriov-dkms.inputs.nixpkgs.follows = "nixpkgs";
    scopebuddy.url = "github:HikariKnight/ScopeBuddy";
    scopebuddy.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs = { self, nixpkgs, home-manager, musnix, nur, i915-sriov-dkms, scopebuddy, ... }@inputs: {
    nixosConfigurations.twilight-desktop-nixos = nixpkgs.lib.nixosSystem {
      modules = [
        musnix.nixosModules.musnix
        i915-sriov-dkms.nixosModules.default
        
        ./configuration.nix
        home-manager.nixosModules.home-manager
        {
          home-manager.useGlobalPkgs = true;
          home-manager.useUserPackages = true;
          home-manager.extraSpecialArgs = { inherit inputs; };
          home-manager.users.twilight = ./home.nix;
        }
      ];
    };
  };
}

and my home.nix to this:

{ config, lib, pkgs, inputs, ... }:
{
  xdg.enable = true;
  home.packages = [ inputs.scopebuddy.packages.${pkgs.system}.default ];
  programs.vesktop = {
    enable = true;

    vencord.settings = {
      autoUpdate = true;
      autoUpdateNotification = true;
      notifyAboutUpdates = true;

      plugins = {
        ClearURLs.enabled = true;
        FixYoutubeEmbeds.enabled = true;
      };
    };
  };
}

I was able to add scopebuddy to my shell. I most likely need to read up more on nix-isms.