Home-manager standalone on Linux Mint crashes Cinnamon on startup

Help
1

I’m running home-manager on Linux Mint with a nix install from the Determinate Systems installer.

Recently I made a change that I cannot trace back that leads to Cinnamon crashing on startup. I recently switched to a flake setup but did not track my changes properly. Do you see any obvious reason that could cause this? Thanks alot!

flake.nix

{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    home-manager.url = "github:nix-community/home-manager";
    home-manager.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs = { nixpkgs, home-manager, ... }:
    let
      system = "x86_64-linux";
      pkgs = nixpkgs.legacyPackages.${system};
    in {
      homeConfigurations.michael = home-manager.lib.homeManagerConfiguration {
        inherit pkgs;

        modules = [ ./home.nix ];
      };
    };
}

home.nix

{ config, pkgs, ... }:
let
  userName = "michael";
  configThemeNormal = ./p10k/.p10k.zsh;
  configThemeTTY = ./p10k/.p10k-tty.zsh;
in {
  home.username = userName;
  home.homeDirectory = "/home/${userName}";
  home.stateVersion = "23.05"; # Please read the comment before changing.
  nixpkgs.config.allowUnfree = true;
  targets.genericLinux.enable = true;
  fonts.fontconfig.enable = true;

  home.packages = with pkgs; [
    tmux
    fontconfig
    guake
    vscode
    zsh
    zsh-powerlevel10k
    zsh-fzf-tab
    fzf
    ripgrep
    meslo-lgs-nf
    osm2pgsql
    nixfmt-classic
    pipx
    rbenv
    pyenv
    yt-dlp
    puddletag
    signal-desktop
  ];
  programs.home-manager.enable = true;
  programs.bat.enable = true;
  programs.fzf.enable = true;
  programs.direnv.enable = true;
  programs.fzf.enableZshIntegration = true;
  programs.git = {
    enable = true;
    hooks = { pre-commit = ./git/pre-commit; };
  };
  programs.gpg.enable = true;
  services.gpg-agent = {
    enable = true;
    defaultCacheTtl = 18000;
    maxCacheTtl = 18000;
  };
  programs.zsh = {
    enable = true;
    enableCompletion = true;
    autosuggestion.enable = true;
    syntaxHighlighting.enable = true;
    oh-my-zsh = {
      enable = true;
      plugins = [ "git" "history" "sudo" ];
    };
    shellAliases = { hms = "home-manager switch"; };
    initExtra = ''
      if zmodload zsh/terminfo && (( terminfo[colors] >= 256 )); then
        [[ ! -f ${configThemeNormal} ]] || source ${configThemeNormal}
      else
        [[ ! -f ${configThemeTTY} ]] || source ${configThemeTTY}
      fi
    '';
    plugins = [
      {
        # A prompt will appear the first time to configure it properly
        # make sure to select MesloLGS NF as the font in Konsole
        name = "powerlevel10k";
        src = pkgs.zsh-powerlevel10k;
        file = "share/zsh-powerlevel10k/powerlevel10k.zsh-theme";
      }
      {
        name = "zsh-autosuggestions";
        src = pkgs.fetchFromGitHub {
          owner = "zsh-users";
          repo = "zsh-autosuggestions";
          rev = "v0.6.3";
          sha256 = "1h8h2mz9wpjpymgl2p7pc146c1jgb3dggpvzwm9ln3in336wl95c";
        };
      }
    ];
  };
}