How can I downgrade a package, using a flakes config?

Help
1

The new version of mu breaks a lot of things, so I’d like to use an older version, version 1.6.x.

My NixOS system is configured using flakes. How would I go about overriding my mu package with its older version? I think I’m installing mu via home-manager.

2

Luckily the build script didn’t change at all, so all you need to do is override it like so:

{
  <snip>
  outputs = {
    self,
    nixos,
    nixos-hardware,
    home-manager,
    nix-doom-emacs,
  }: let
    overlays = [
      (final: prev: {
        mu = prev.mu.overrideAttrs (_: rec {
          version = "1.6.9";

          src = fetchFromGitHub {
            owner = "djcb";
            repo = "mu";
            rev = version;
            sha256 = "RoSj283fcllEbirZOScKRU4BKLoxgatDdL1qYZu+LEI=";
          };
        });
      })
    ];
  in {
    nixosConfigurations.jon-laptop = nixos.lib.nixosSystem {
      system = "x86_64-linux";
      modules = [
        ({...}: {
          nixpkgs.overlays = overlays;
        })
        <snip>
      ];
    };
  };
}

Apply architecture rejigging so it’s a bit prettier as you please :slight_smile:

Alternatively, you can depend on an older revision of nixpkgs for that package, which is a nice escape hatch if there was a more complex change to the package:

{
  <snip>
  inputs = {
    home-manager = {
      url = "/home/jon/Code/home-manager";
      inputs.nixpkgs.follows = "nixos";
    };
    nix-doom-emacs.url = "github:nix-community/nix-doom-emacs";
    nixos-hardware.url = github:NixOS/nixos-hardware/master;
    nixos.url = "nixpkgs/nixos-unstable";
    nixos-old.url = "nixpkgs/nixos-unstable?rev=db93862a2c777135e0af3e9c7b0bbcba642c8343";
  };
  outputs = {
    self,
    nixos,
    nixos-hardware,
    nixos-old,
    home-manager,
    nix-doom-emacs,
  }: let
    overlays = [
      (final: prev: {
        mu = nixos-old.legacyPackages.${prev.system}.mu;
      })
    ];
  in {
    nixosConfigurations.jon-laptop = nixos.lib.nixosSystem {
      system = "x86_64-linux";
      modules = [
        ({...}: {
          nixpkgs.overlays = overlays;
        })
        <snip>
      ];
    };
  };
}

But this means that in time you will have two versions of nixpkgs, which will increase the size of your downloads and installation, and is a bad idea when you try to do it with stuff like graphical applications that depend on things with specific versions at runtime, rather than just at the library level (like most graphical applications that depend on Xorg and your graphics drivers).

Oh, since you mention it, home-manager ultimately uses nixpkgs packages. When you configure it using the NixOS module, it will use the same nixpkgs as your system - so overriding the mu package in your system nixpkgs will override the mu package that home-manager uses.

1 Like
3

The build script did change massively in the 1.6 to 1.8 transition, it changed from autoconfigure+make to a meson bases build, so the strategy of using an earlier nixpkgs revision is probably easier in this case.

4

Ah, you’re right, I’m blind and missed the unstable there. Switching to stable for this package, rather than using a pinned revision, is probably the better option then.