How can I install `jquery` and `bootstrap4` from nixpkgs for `prosody.nix` `mod_invites`?

Help
1

Is it in nixpkgs? thanks.

External dependencies

The default HTML templates for the web-based modules1 depend on the Bootstrap 4 CSS and JavaScript libraries, and the jQuery library. They expect these to be available at https://example.com/share.

An easy way to provide theam instead if you are on Debian 10 (buster) is to enable mod_http_libjs and install the following packages:

apt install libjs-bootstrap4 libjs-jquery

On other systems you will need to manually fetch and put these libraries somewhere on the filesystem that Prosody can read, and serve them using mod_http_libjs with a custom libjs_path setting.

2

@toastal is the maintainer for this package on nixpkgs, maybe he can help.

3

You could try putting the files on a reverse proxy in front of the XMPP server, but I can’t say I know much about this particular situation or why they thought they needed jQuery or Bootstrap dependencies for this task… 1. who knows what version the host really comes with, 2. we can see they vendored QR code scanning + UA detection already, & 3. there really isn’t much code to begin with so it is such a huge dependency (4. there practices too that look like HTML dev from last decade).

1 Like
4

My ugly solution:

  1. add a package with both bootstrap4 and jquery, say ./libjs-bootstrap4-jquery/default.nix
{
  stdenv,
  fetchzip,
}:
let
  pname = "libjs-bootstrap4-jquery";
  version = "0.0.1";
  src = fetchzip {
    # bootstrap 4.6.2
    url = "https://github.com/twbs/bootstrap/releases/download/v4.6.2/bootstrap-4.6.2-dist.zip";
    hash = "sha256-RfZgtHnhTDCWdNuVDnQfF5VsXrSqyCqPoLN+5hzpBhI=";
  };
  jquery = stdenv.mkDerivation (finalAttrs: {
    pname = "jquery";
    version = "3.7.1";
    src = fetchzip {
      # jquery 3.7.1
      url = "https://github.com/jquery/jquery/archive/refs/tags/3.7.1.zip";
      hash = "sha256-U96UOF1HQ5NgMuIDFIwcGUSFOuuJ8Wrs8PuqMbxh30M=";
    };
    installPhase = ''
      runHook preInstall
      # find . -type f
      mkdir -p $out
      cp -rv -t $out ./dist/{jquery.js,jquery.min.js,jquery.min.map,jquery.slim.js,jquery.slim.min.js,jquery.slim.min.map}
      runHook postInstall
    '';
  });
in
stdenv.mkDerivation (finalAttrs: {
  inherit pname version src;
  installPhase = ''
    runHook preInstall
    mkdir -p $out/{bootstrap4,jquery}
    mkdir -p $out/bootstrap4/{js,css}
    cp -rv -t $out/bootstrap4/js/  ./js/*
    cp -rv -t $out/bootstrap4/css/ ./css/*
    cp -rv -t $out/jquery ${jquery}/*
    runHook postInstall
  '';
})
  1. add the package outpath to libjs_path
services.prosody.extraConfig = ''
  libjs_path = "${(pkgs.callPackage (self + ./libjs-bootstrap4-jquery) { }).outPath}";
'';
5

Seems like the right idea to cache these versions yourself but code looks a bit messy with that jquery just floating in the derivation like it is. It’s probable srcs (not src) could make this in a single mkDerivation. You can also switch to stdenvNoCC over stdenv since you don’t need a C compiler, but you likely could just runCommand & cp your srcs to $out. I also don’t think you need every version of jquery instead of just jquery.min.js (or rename the one you want to the name the module is looking for). Current (not using srcs) installPhase could probably shorter like

runHook preInstall
mkdir -p $out/bootstrap4
cp -r ./js ./css $out/bootstrap4/
cp -Trf ${jquery} $out/jquery
runHook postInstall
1 Like