How to disable some panels in GNOME control center

[vccs]

@jtojnar

current-system is just another immutable package that symlinks stuff in environment.systemPackages (built with buildEnv).

You could inject extra code to environment.extraSetup NixOS option to remove the desktop files from the symlink tree. But that might require manual reification of symlinks if you are unlucky and the files you want to remove are inside a symlink to a directory in another package. And it will not help you if a package looks directly to g-c-c Nix store path, you would need to update the references in the package. At that point, you might want to use system.replaceRuntimeDependencies hack but that is a bit tricky.

Alternately, you could install a package with higher priority to environment.systemPackages, that would contain a dummy version of the files you want to remove. But again, that will not work if a package looks directly to g-c-c Nix store path.

Anyway, this is getting off-topic so please open a new thread if you want discuss this avenue further.

The panels can be disabled by remove the corresponding desktop files according to Is it possible to remove items from "System Settings" - Ask Ubuntu. But it’s not easy on NixOS. I tried to add a dummy package with empty desktop files. But it doesn’t work. Maybe it’s easier to create a wrapper for GNOME control center.

[jtojnar]

What exactly did you try?

[vccs]

    (pkgs.writeTextFile {
      name = "gnome-online-accounts-panel";
      text = "";
      destination = "/share/applications/gnome-online-accounts-panel.desktop";
    })

Add this to systemPackages, then the gnome-online-accounts-panel.desktop in current-system will be an empty file. But the panel is still there. I tested patching the package and it does work by removing the file. But I don’t want to add another minute when I rebuilding the system so I’ll use a wrapper.

[vccs]

      gnome = super.gnome // {
        gnome-control-center = super.runCommand "gnome-control-center" { } ''
          mkdir -p $out
          ${super.xorg.lndir}/bin/lndir -silent ${super.gnome.gnome-control-center} $out
          rm $out/share/applications/gnome-{online-accounts,sharing}-panel.desktop
        '';
      };

This doesn’t work either. I guess it looks at the original path.

[jtojnar]

Right, try copying the files and then seding the original path for the new one.

[vccs]

      gnome = super.gnome // {
        gnome-control-center = super.runCommand "gnome-control-center" { } ''
          cp -R ${super.gnome.gnome-control-center} $out
          chmod -R +w $out
          rm $out/share/applications/gnome-{online-accounts,sharing}-panel.desktop
          find $out -type f -exec sed -i -e "s|${super.gnome.gnome-control-center}|$out|g" {} \;
        '';
      };
    })

This doesn’t work either.

[vccs]

I know why it didn’t work. The path must has same length so the name should match. This is the working code:

      gnome = super.gnome // {
        gnome-control-center = super.runCommand "${super.gnome.gnome-control-center.name}" { } ''
          cp -R ${super.gnome.gnome-control-center} $out
          chmod -R +w $out
          rm $out/share/applications/gnome-{online-accounts,sharing}-panel.desktop
          find $out -type f -exec sed -i -e "s|${super.gnome.gnome-control-center}|$out|g" {} \;
        '';
      };