Install nix package without adding to GNOME apps screen

[Richienb]

When I install pkgs.vim by putting it in systemPackages, it also gets added to the GNOME apps screen (when I click on it it opens a terminal screen where vim is open).
How do I install vim without it appearing in the apps screen?

[knoopx]

override the derivation and rm *.desktop files from the output, example:

final: prev: let
  withoutDesktopIcon = pkg:
    pkg.overrideAttrs (origAttrs: {
      postInstall = ''
        ${origAttrs.postInstall or ""}
        rm -rf $out/share/applications/*.desktop
      '';
    });
in {
  htop = withoutDesktopIcon prev.htop;
  btop = withoutDesktopIcon prev.btop;
  micro = withoutDesktopIcon prev.micro;
  fish = withoutDesktopIcon prev.fish;
}```

[waffle8946]

Better option:

Make neovim wrapper .desktop optional

I doubt there are any conventions about this specific thing since it is such an obscure request. So the decision whether to accept a PR for this feature would fall to the maintainers of the package. Personally, I would consider the costs compared to benefits (with alternatives in mind) and reject it: Costs Added complexity to the package expression. People might disable the launcher not realizing that it would also break file associations. Benefits ¿One? user’s non-critical (purely cosmetic…

[TLATER]

Specifically this part is probably the best approach:

@jtojnar

User can do something like the following in their NixOS configuration to hide the launcher from the Shell:

{ config, lib, pkgs, ... }:
{
  environment.systemPackages = [
    (lib.hiPrio (pkgs.runCommand "nvim.desktop-hide" { } ''
      mkdir -p "$out/share/applications"
      cat "${config.programs.neovim.finalPackage}/share/applications/nvim.desktop" > "$out/share/applications/nvim.desktop"
      echo "Hidden=1" >> "$out/share/applications/nvim.desktop"
    ''))
  ];
}

Or use NoDisplay instead of Hidden if you want file associations to keep working.

That’s the intended-by-freedesktop mechanism.