Issues with overlay to include newer package

taylskid · June 24, 2020, 8:49pm

I am running NixOS 20.03 and would like to install Gerbil Scheme. Currently, only 0.15.1 is available, but 0.16 is available in unstable. I honestly considering just jumping to unstable, but I thought this would be a good time to stretch my nix muscles a little, so I am trying to write an overlay.

Here’s my overlay.nix, the vars are basically verbatim from what’s in the unstable nixpkgs:

self: super:

{
  gerbil = super.gerbil.overrideAttrs ( oldAttrs: rec {
    version = "0.16";
    git-version = version;
    src = self.fetchFromGitHub {
      owner = "vyzo";
      repo = "gerbil";
      rev = "v${version}";
      sha256 = "0vng0kxpnwsg8jbjdpyn4sdww36jz7zfpfbzayg9sdpz6bjxjy0f";
    };
  });
}

and my shell.nix:

{ nixpkgs ? import <nixpkgs> { overlays = [(import ./overlay.nix)]; } }:
nixpkgs.mkShell {
  buildInputs = [nixpkgs.gerbil];
}

When I run this, it appears to run correctly, it mentioned unpacking source archive /nix/store/3bhsqprh02qr5aana5bdz20ysb53hdbz-source, and when I checked that directory it does appear to have the correct version source: (define (gerbil-version-string) "v0.16"). However once it finishes building, and the shell launches, it loads gerbil 0.15.1!

[nix-shell:~/work/gerbil]$ gxi
Gerbil v0.15.1 on Gambit v4.9.3
[nix-shell:~/work/gerbil]$ which gxi
/nix/store/n0fwpf0r83xdy48wx7d1sxmf4kdv6p8z-gerbil-0.16/bin/gxi

That nix store link appears to be correct based on the build output from when I ran nix-shell so it appears to have build 0.15.1 or 0.15.1 has otherwise leaked into the build. Does anyone have any idea for how I may proceed?

alexarice · June 26, 2020, 1:27pm

github.com

NixOS/nixpkgs/blob/28ea6a7ec2a1f68c79998a66840b34a06f94e3d6/pkgs/development/compilers/gerbil/build.nix#L26


      
          
          
  # TODO: either fix all of Gerbil's dependencies to provide static libraries,
            # or give up and delete all tentative support for static libraries.
            #buildInputs_staticLibraries = map makeStaticLibraries buildInputs_libraries;
          
          
  buildInputs = [ gambit ]
              ++ buildInputs_libraries; # ++ buildInputs_staticLibraries;
          
          
  NIX_CFLAGS_COMPILE = "-I${libmysqlclient}/include/mysql -L${libmysqlclient}/lib/mysql";
          
          
  postPatch = ''
              echo '(define (gerbil-version-string) "v${git-version}")' > src/gerbil/runtime/gx-version.scm ;
              patchShebangs . ;
              grep -Fl '#!/usr/bin/env' `find . -type f -executable` | while read f ; do
                substituteInPlace "$f" --replace '#!/usr/bin/env' '#!${coreutils}/bin/env' ;
              done ;
          '';
          
          
## TODO: make static compilation work.
          ## For that, get all the packages below to somehow expose static libraries,
          ## so we can offer users the option to statically link them into Gambit and/or Gerbil.

The builder for gerbil seems to patch in the correct version, which is likely why it reports being version 0.16. However I don’t know why the correct version is not being used

taylskid · June 26, 2020, 3:10pm

I have managed to get this to work, thanks in part to your insightful comment alexarice, and thanks in part to balsoft in the Nix room on Matrix.org

postPatch was indeed my problem! I believe I was actually building and running Gerbil 0.16 the entire time, and this postPatch call was what was overwriting the version number that I could see in the repl. When I check for a function introduced in 0.16, it does also appear in my “0.15.1 repl.”

When I passed in that same postPatch via overrideAttrs everything worked as expected. I believe this could be “fixed” by adjusting postPatch to use "v$git-version" to do that variable substitution at package-build-time rather than nix-compile-time, although I’m not sure if this will be accepted.

The final overlay.nix for those following along at home:

self: super:

{
  gerbil = super.gerbil.overrideAttrs ( oldAttrs: rec {
    version = "0.16";
    git-version = version;
    postPatch = ''
      echo '(define (gerbil-version-string) "v${git-version}")' > src/gerbil/runtime/gx-version.scm ;
      patchShebangs . ;
      grep -Fl '#!/usr/bin/env' `find . -type f -executable` | while read f ; do
        substituteInPlace "$f" --replace '#!/usr/bin/env' '#!${self.coreutils}/bin/env' ;
      done ;
    '';
    src = self.fetchFromGitHub {
      owner = "vyzo";
      repo = "gerbil";
      rev = "v${version}";
      sha256 = "0vng0kxpnwsg8jbjdpyn4sdww36jz7zfpfbzayg9sdpz6bjxjy0f";
    };
  });
}