Override python3Package using overlay

Help
1

Currently the khal package is broken because of an upstream issue, for which a PR has been opened. I’m trying to apply the PR to my system using an overlay. But can’t get it to work. Normally i add packages using this logic. Where inputs is just the inherited flake inputs variable of this entire file

  leantime = _final: prev: {
    leantime = inputs.nixpkgs-personal.legacyPackages.${prev.system}.leantime;
  };

But I can’t quite figure out how to do this for a python package.

2

This is documented in the nixpkgs manual.

3

That seems to be for overriding the bulid ov a python package. But I couldn’t find anything on how to override the python package with one from a different input.

Edit: I’m trying to fix the build of package khal. Which should be fixed by the PR(according to this issue. But overriding the package in an overlay like this still gives me the same build failure for khal that I got before applying the overlay:

  sphinxfix = _final: prev: {
    python3 = prev.python3.override {
      packageOverrides = python-self: python-super: {
        sphinxcontrib-newsfeed =
          inputs.nixpkgs-master.legacyPackages.${prev.system}.python3Packages.sphinxcontrib-newsfeed;
      };
    };
  };
4

Overriding part of the build and replacing the package in its entirety ultimately result in the same thing, a different path in the nix store for the package.

I have tried this in my own configuration, the gist of what I have done is this:

inputs = {
  nixpkgs.url = “https://channels.nixos.org/nixos-25.11/nixexprs.tar.xz”;
  nixpkgs2.url = “git+file:///data/code/nixpkgs”;
}

outputs = {
  self,
  nixpkgs,
  nixpkgs2,
  ...
}:
{
  nixosConfigurations = nixpkgs.lib.nixosSystem {
    modules = [
      {
        nixpkgs.overlays = [
          (self: super: {
            python3 = super.python3.override {
              packageOverrides = python-self: python-super: {
                pandas = nixpkgs2.legacyPackages.${system}.python3Packages.pandas;
              };
            };
          })
        ];
      }
  };
5

Okay. I have reviewed the derivation for khal upstream. We need to override python3Packages rather than python3. Here is a minimum working example.

{
  description = "Build khal";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    fixed.url = "github:NixOS/nixpkgs/be497847c9adc1ca52659bd64ee2a398cec6bc9e";
  };

  outputs = { self, nixpkgs, fixed }:
    let
      system = "x86_64-linux";
      pkgs = import nixpkgs {
        inherit system;
        overlays = [
          (self: super: {
            python3Packages = super.python3Packages.override {
              overrides = python-self: python-super:  {
                sphinxcontrib-newsfeed = fixed.legacyPackages.${system}.python3Packages.sphinxcontrib-newsfeed;
              };
            };
          })
        ];
      };
    in
    {
      packages.${system}.default = pkgs.khal;
    };
}
6

Note that overlaying what python3Packages is aliased to (currently python313Packages) will propagate to the alias, but overlaying just the alias will not propagate to the versioned packageset.

1 Like