Request to upstream out-of-tree packages

Development Patches
1

Hi,

I maintain (out-of-tree, for my own uses, no GitHub account anymore) a couple of packages. Curious if anyone wants to submit a PR for these (I’m no good for a maintainer role, as no GitHub account)? If not, feel free to add them to your own out-of-tree list.

Geany-plugins (package.nix):

{ stdenv
, lib
, fetchurl
, intltool
, pkg-config
, file
, geany
, gtk3
, glib
, vte
, ctpl
, lua5_1
, gpgme
, libsoup_3
, enchant
, webkitgtk_6_0
, libgit2
, gtkspell3
}:

stdenv.mkDerivation rec {
  pname = "geany-plugins";
  version = "2.1";

  src = fetchurl {
    url = "https://plugins.geany.org/geany-plugins/${pname}-${version}.tar.gz";
    sha256 = "sha256-d+w9oHvoCTV7qcmG6bctLso0MAjMwHk2c8ncrCrY2uE=";
  }; 

  nativeBuildInputs = [
    intltool
    pkg-config
    file
    geany
    vte
    ctpl
  ];

  buildInputs = [
    gtk3
    lua5_1
    gpgme
    libsoup_3
    enchant
    webkitgtk_6_0
    libgit2
    gtkspell3
  ];

  propagatedBuildInputs = [
    glib
    gtk3
  ];

  # Undeclared dependency upstream
  # See https://github.com/NixOS/nixpkgs/issues/36468
  NIX_CFLAGS_COMPILE = "-I${glib.dev}/include/gio-unix-2.0";

  preConfigure = ''configureFlags="--with-geany-libdir=$out/lib"'';
  enableParallelBuilding = true;

  meta = with lib; {
    description = "Geany IDE plugins";
    longDescription = ''
      Plugins provided by the Geany Plugins Project. The built plugin libraries
      path needs to be manually linked or referenced by Geany for the plugins to
      be found (see the Plugins section of the Geany manual). 
    '';
    homepage = "https://plugins.geany.org/";
    license = licenses.gpl3Plus;
    platforms = platforms.all;
  };
}

xfce4-wavelan-plugin(package.nix) –Note: Better integration with mkXfceDerivation{} needed for NixOS upstream

{ lib
, stdenv
, pkg-config
, intltool
, xfce4-panel
, libxfce4ui
, xfconf
, fetchFromGitLab
, meson
, ninja
}:

let
  category = "panel-plugins";
in stdenv.mkDerivation rec {
  pname  = "xfce4-wavelan-plugin";
  version = "0.7.0";

  src = fetchFromGitLab {
    domain = "gitlab.xfce.org";
    owner = "panel-plugins";
    repo = "xfce4-wavelan-plugin";
    rev = "${pname}-${version}";
    sha256 = "sha256-j8rKlCxA3gnQSIeQZL+wcGlHpVJDCS66PjrD3MAeb50=";
  };

  nativeBuildInputs = [
    meson
    ninja
    pkg-config
    intltool
  ];

  buildInputs = [
    libxfce4ui
    xfce4-panel
    xfconf
  ];

  enableParallelBuilding = true;

  meta = with lib; {
    homepage = "https://docs.xfce.org/panel-plugins/xfce4-wavelan-plugin";
    description = "Display stats from a wireless LAN interface in the Xfce panel";
    license = licenses.gpl2Plus;
    platforms = platforms.linux;
  };
}

Thanks

2

That’s a bit of an odd request ^^’’
You can publicize packages without upstreaming via nur:

https://nix-community.github.io/nur-search/

or the experimental flake registry https://search.nixos.org/flakes?type=packages

3

There’s still no formal way for someone boycotting GH to submit to either of those, right?

4

The patches category on Discourse is explicitly used for this purpose, but still depends on someone motivated to make a PR.

1 Like
5

apologies for the snark, didn’t see the category /o\

6

As these are new packages, it would be good to have someone wanting to do at least a bit of maintenance on them in the future.

1 Like
7

Yes it’d be proper for someone to fill in the maintainer field :wink: (As I said without GitHub access I’m not much value there). I should note both packages are pretty low churn (could be a year or so between updates).

Thanks,